カテゴリー「マクロプログラム」の50件の記事

2010年7月 3日 (土)

使用中の書式を検索するマクロ

文書を作成するときに、いろいろと書式を使いますね。

私は、メモとしていろいろな書式を書き込みますが、納品時にはそれらのメモがないことを確認する必要があります。

そんなときに便利なマクロです。

Sub Style_Check()

      Dim myRange As Range
      Dim myStyle(1 To 7) As String
      Dim i As Integer
      Dim myStyleFound As String
      Dim blnStyle As Boolean

10    myStyle(1) = "下付き"
20    myStyle(2) = "上付き"
30    myStyle(3) = "太字"
40    myStyle(4) = "斜体"
50    myStyle(5) = "下線(一重線)"
60    myStyle(6) = "取り消し線"
70    myStyle(7) = "蛍光ペン"

80    For i = 1 To 7

90        Set myRange = ActiveDocument.Range(0, 0)

100       With myRange.Find
110           .Text = ""
120           .Forward = True
                     
130           If i = 1 Then
140               .Font.Subscript = True
150           ElseIf i = 2 Then
160               .Font.Superscript = True
170           ElseIf i = 3 Then
180               .Font.Bold = True
190           ElseIf i = 4 Then
200               .Font.Italic = True
210           ElseIf i = 5 Then
220               .Font.Underline = wdUnderlineSingle
230           ElseIf i = 6 Then
240               .Font.StrikeThrough = True
250           ElseIf i = 7 Then
260               .Highlight = True
270           End If

280           .Wrap = wdFindStop
290           .Execute
             
300           If .Found = True Then
310               myStyleFound = myStyleFound & vbCr & myStyle(i)
320           End If
             
330       End With

340   Next

350   Set myRange = Nothing

360   If Len(myStyleFound) <> 0 Then
370       MsgBox "現在の文書で使用されている書式" & vbCr & myStyleFound, vbInformation, "検索結果"
380   Else
390       MsgBox "見つかりませんでした。", vbExclamation, "検索結果"
400   End If

End Sub

| | コメント (0) | トラックバック (0)

2010年6月 4日 (金)

シンボルフォントを着色するマクロ

シンボル(Symbol)フォントって、検索できなくないですか?

水野麻子さんの記事「Symbolフォントは危険!」にもあるのですが、ワード上のシンボルフォントって、エディターソフトで文字化けするし、やっかいですね。

そこで、シンボルフォントの一部ではありますが、検索するマクロです。

ギリシャ文字部分(大文字・小文字)をピンクに着色します。

Sub Symbolフォント探し()

Dim SS, SE As Long 'カーソル位置の保存用

'画面更新非表示
    Application.ScreenUpdating = False

'カーソルの現在位置を保存
    SS = Selection.Start
    SE = Selection.End
            
'シンボルフォントのギリシャ文字をピンクの蛍光ペンで着色
For i = 61505 To 61562
If i >= 61531 And i <= 61536 Then GoTo Proc_Skip

    Selection.Find.ClearFormatting
    Selection.Find.Replacement.ClearFormatting
    With Selection.Find
        .Text = ChrW(i)
        .Forward = True
        .Wrap = wdFindContinue
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchByte = False
        .MatchAllWordForms = False
        .MatchSoundsLike = False
        .MatchWildcards = False
        .MatchFuzzy = True
        .Execute
    End With
   
    Do While Selection.Find.Found = True
        Selection.Range.HighlightColorIndex = wdPink
        Selection.Find.Execute
    Loop
   
Proc_Skip:
Next i

'▼検索・置換条件の初期化
    Selection.Find.ClearFormatting
    Selection.Find.Replacement.ClearFormatting
    With Selection.Find
        .Text = ""
        .Replacement.Text = ""
        .Forward = True
        .Wrap = wdFindContinue
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchByte = False
        .MatchAllWordForms = False
        .MatchSoundsLike = False
        .MatchWildcards = False
        .MatchFuzzy = True
        .Execute
    End With

'カーソルの位置を戻す
    Selection.Start = SS
    Selection.End = SE

'画面更新表示
    Application.ScreenUpdating = True
   
End Sub

| | コメント (0) | トラックバック (0)

2010年5月 1日 (土)

使用中の文字サイズ検出するマクロ

文書で使用されている文字の大きさを表示するマクロです。

▼作成経緯

他の方がつくった文書って、その人のクセがありますよね。

ちなみに、私が作る文書もかなりクセがあります。

実害がない部分だと思うのですが、ヘッダーに案件番号を埋め込んであったり

文書ごとに変数を設定して、記憶させていたり。

これはマニアックな使い方ですが、機会があれば紹介します。

で、もっとわかりやすいところで、文字のサイズの使い方です。

職場のある方は、「下付き文字」を表示するために、文字サイズを小さくしていました。

具体的には、

 全体の標準的な文字の大きさ 12ポイント

 下付きに表示させたい文字の大きさ 8ポイント

です。

上記の8ポイントを使った表示と、下付き文字を使った表示の比較はこんな感じ。

Fontsize

たしかに、8ポイントを使った表示(上記①)でも、わからないこともない。

本人曰く、「文字の下端部分がそろっていて美しい」とのこと。

「なるほど!」という考え方です。こういう工夫いいですね。

でも、他の人と文書を共有して使い回す場合には、あまりうれしくないです。。。

だって、このことを知らずに編集をしたりするとトラブルの原因になりえます。

たとえば、文字のサイズを10.5ポイントに変更するために、

全選択をして文字サイズを変更することもあるかも。

そうしたら、12ポイントと8ポイントで表示していた化学式が

すべて10.5ポイントになってしまい、下付き文字がなくなります。

というわけで、現在使われている文字サイズがいくつなのかを表示する

マクロを作ってみました。

▼作用

文書中の文字サイズを1~100まで0.5ポイントごとに有無を確認します。

最終的に、使われている文字のサイズをメッセージボックスで表示します。

Fontsize2

▼プログラムの工夫

20行から140行で、For Nextの繰り返し処理をします。

このときのstepを0.5としました。

文字の大きさをしめすmySizeという変数に入れる値を

1~100まで変更して繰り返します。

そのときに1、1.5、2、2.5 ・・・・ 99.5、100 と

段階をおうようにしました。

stepには、マイナスの値も入れられます。

たとえば、100、99.5 ・・・・ 1.5、1と逆にすることも

できます。

その場合には、20行のところを

  For mySize = 100 To 1 Step -0.5

と表記します。

▼登録方法

以下のページをご覧ください。

○ ワードマクロの作成(ver.95~2003)
○ ワードマクロの作成(ver.2007)
○ マクロにショートカットを割り当てる

▼プログラム

Sub 使用中の文字サイズ検出()

Dim myRange As Range
Dim mySize As Single
Dim FontSize As String

10 Set myRange = ActiveDocument.Range(0, 0)

20 For mySize = 1 To 100 Step 0.5

30 myRange.SetRange Start:=0, End:=0

40 With myRange.Find
50 .Text = ""
60 .Forward = True
70 .Font.Size = mySize
80 .Wrap = wdFindStop
90 .Execute

100 If .Found = True Then
110 FontSize = FontSize & "、" & mySize
120 End If

130 End With

140 Next

150 MsgBox "使用中の文字サイズは" & FontSize & "です。"

160 Set myRange = Nothing

End Sub

| | コメント (0) | トラックバック (0)

2010年4月25日 (日)

テンプレートの編集マクロ

使用中のテンプレートをVBEで編集する場合、手間ですね。

①テンプレートとアドイン のダイアログボックスから
対象となるテンプレートを選んでオフにする。

②対象となるテンプレートが保存されているフォルダを開く

③対象となるテンプレートを「開く」で開く
通常のようにダブルクリックすると、テンプレート自体が
開かれるのではなくて、テンプレートから作られた文書が
開かれてしまいます。

私のように、個別のテンプレートにマクロを保存している方、
同じような手間を経験されたことがあると思います。

そんなわけで、こんなマクロを作ってみました。

▼作用
①このプログラムを動かすと、ユーザーテンプレートフォルダを起動します。

②フォルダから編集対象のテンプレートをダブルクリックすると
 そのテンプレートがVBEで開きます。

▼工夫
いつもと表現をかえて、

  .InitialFileName = "%appdata%\microsoft\templates\*.dot"

として、ユーザーテンプレートフォルダを指定しました。

▼プログラム
Sub テンプレートをVBEで編集する()

Dim fd As FileDialog
Dim TemplateName As String
Dim myAdd As AddIn

Set fd = Application.FileDialog(msoFileDialogOpen)

With fd
   .Title = "VBEで編集するテンプレートの選択"
   .InitialFileName = "%appdata%\microsoft\templates\*.dot"
   .AllowMultiSelect = False
   If .Show = -1 Then
       TemplateName = .SelectedItems(1)
   Else
       End
   End If
End With

'テンプレートをオフにする
For Each myAdd In AddIns  '登録されているかを調べる
    If myAdd.Name = TemplateName Then
        AddIns(TemplateName).Installed = False
    End If
Next

'テンプレートを開く
Documents.Open FileName:=TemplateName

'VBEを開く
ShowVisualBasicEditor = True

End Sub

| | コメント (0) | トラックバック (0)

2010年4月24日 (土)

文字書式を保存/復元するマクロ

太字、下付き、上付きなど、文字の書式が設定されている文章を
テキストエディターで編集したいときありませんか?

通常、この文章をテキストエディタにコピーすると、書式がすべて
なくなってしまいますね。

そんな悩みを解決するマクロです。

▼用途
ウェブやワードの文章をテキストエディタで編集する場合に、
必要最小限の文字書式を保持できます。

編集が終わった後、ワードにコピーしたテキスト情報にもとの
文字書式を復元します。

▼作用
①これらの書式をhtmlで使われるタグに変換します。(プログラム1)
②テキストエディターで編集
③タグを書式に戻します。(プログラム2)

▼保持できる文字書式
以下の6種類です。各プログラムの10行~60行に定義しました。

下付き
上付き
太字
斜体
下線(一重線)
取り消し線

▼工夫
プログラム1の70行~90行に、フィールドやリンクの設定を
解除するコードを挿入しました。

ウェブから文章をコピーした場合に、なんらかの情報が文字に
組み込まれていると、タグ化が正常に作動しない場合があります。

これを回避するために、文字に組み込まれた情報をまず削除してから
タグ化をしています。

以前こちらで紹介したマクロの改良版です。

▼プログラム1 書式をテキスト情報(タグ)に変換

Sub 文字書式をタグ化()
         
      Dim myRange As Range
      Dim myChr(1 To 6) As String
      Dim i As Integer
      Dim aField As Field

      '下付き
10    myChr(1) = "sub"
      '上付き
20    myChr(2) = "sup"
      '太字
30    myChr(3) = "b"
      '斜体
40    myChr(4) = "i"
      '下線(一重線)
50    myChr(5) = "u"
      '取り消し線
60    myChr(6) = "s"

      'フィールドのリンク削除(太字の無限ループに入ることがあるから)
70    For Each aField In ActiveDocument.Fields
80        aField.Unlink
90    Next aField

      '書式のタグ化
100   For i = 1 To 6
110       Set myRange = ActiveDocument.Range(0, 0)

120       With myRange.Find
130          .Wrap = wdFindStop
140           If i = 1 Then
150               .Font.Subscript = True
160           ElseIf i = 2 Then
170               .Font.Superscript = True
180           ElseIf i = 3 Then
190               .Font.Bold = True
200           ElseIf i = 4 Then
210               .Font.Italic = True
220           ElseIf i = 5 Then
230               .Font.Underline = wdUnderlineSingle
240           ElseIf i = 6 Then
250               .Font.StrikeThrough = True
260           End If
270          .Execute findText:=""
280       End With
         
290       Do While myRange.Find.Found = True
300           With myRange
310               If i = 1 Then
320                   .Font.Subscript = False
330               ElseIf i = 2 Then
340                   .Font.Superscript = False
350               ElseIf i = 3 Then
360                   .Font.Bold = False
370               ElseIf i = 4 Then
380                   .Font.Italic = False
390               ElseIf i = 5 Then
400                   .Font.Underline = wdUnderlineNone
410               ElseIf i = 6 Then
420                   .Font.StrikeThrough = False
430               End If
440           End With
             
450           With Selection.Range
460               .SetRange Start:=myRange.End, End:=myRange.End
470               .Text = "</" & myChr(i) & ">"
480               .SetRange Start:=myRange.Start, End:=myRange.Start
490               .Text = "<" & myChr(i) & ">"
500           End With
             
510           myRange.Collapse
520           myRange.Find.Execute
530       Loop
         
540   Next

550   Set myRange = Nothing

End Sub

▼プログラム2 テキスト情報(タグ)を書式に変換

Sub 文字書式の復元()
         
      Dim myRange As Range
      Dim myChr(1 To 6) As String
      Dim i As Integer

      '下付き
10    myChr(1) = "sub"
      '上付き
20    myChr(2) = "sup"
      '太字
30    myChr(3) = "b"
      '斜体
40    myChr(4) = "i"
      '下線(一重線)
50    myChr(5) = "u"
      '取り消し線
60    myChr(6) = "s"

70    For i = 1 To 6
80        Set myRange = ActiveDocument.Range(0, 0)

90        With myRange.Find
100          .Wrap = wdFindStop
110          .MatchWildcards = True
120          .Execute findText:="[<]" & myChr(i) & "[>]*[<][/]" & myChr(i) & "[>]"
130       End With
         
140       Do While myRange.Find.Found = True
150           With myRange
160               If i = 1 Then
170                   .Font.Subscript = True
180               ElseIf i = 2 Then
190                   .Font.Superscript = True
200               ElseIf i = 3 Then
210                   .Font.Bold = True
220               ElseIf i = 4 Then
230                   .Font.Italic = True
240               ElseIf i = 5 Then
250                   .Font.Underline = wdUnderlineSingle
260               ElseIf i = 6 Then
270                   .Font.StrikeThrough = True
280               End If
290           End With
             
300           With Selection.Range
310               .SetRange Start:=myRange.End, End:=myRange.End - Len(myChr(i)) - 3
320               .Delete
330               .SetRange Start:=myRange.Start, End:=myRange.Start + Len(myChr(i)) + 2
340               .Delete
350           End With
             
360           myRange.Collapse
370           myRange.Find.Execute
380       Loop

390   Next

400   Set myRange = Nothing

End Sub

| | コメント (0) | トラックバック (0)

2010年4月22日 (木)

カーソル位置より前に同じ文字列が記載されているか調べるマクロ

翻訳の最中に、特定の名称の冠詞はtheなのか、aなのか、迷ったことありませんか?

いや、複雑な定冠詞と不定冠詞の話をしているのではなくて、たた単純に
この名称が今までの文中に出てきたのかどうか、調べることなんですが。

▼作用
選択した文字列が、選択したカーソルの位置よりも前に記載されているのかどうか
を調べるマクロです。

▼工夫
メッセージボックスで対話をしながら、出てくる文字列の位置を確認
することができます。

Maekisai

「はい(Y)」をクリックすると、次の検索をします。

「いいえ(N)」をクリックすると、最初に選択した文字列の位置に
カーソルが戻ります。

私は、[Alt] + [F]に登録して使っています。

▼プログラム
Sub 前記載の確認()

Dim myRange As Range
Dim Msg, Style, Title, Response As String
Dim SS, SE As Long
Dim FoundBln As Boolean

SS = Selection.Start
SE = Selection.End
FoundBln = False

'文字列が選択されていない場合には終了
If SS = SE Then End

'表示される言葉の設定
Msg = "次を検索しますか?"
Style = vbYesNo + vbQuestion + vbDefaultButton2
Title = "検索結果"

Set myRange = ActiveDocument.Range(0, 0)
With myRange.Find
    .Wrap = wdFindStop
    .Execute findtext:=Selection.Text
   
    Do While .Found = True
        If myRange.Start <> SS Then
            FoundBln = True
            myRange.Select
            Response = MsgBox(Msg, Style, Title)
            If Response = vbYes Then
                myRange.Collapse direction:=wdCollapseEnd
                .Execute
            Else
                Exit Do
            End If
        Else
            If FoundBln = False Then
                MsgBox "見つかりませんでした。"
                Selection.Collapse direction:=wdCollapseEnd
                End
            Else
                MsgBox "これ以上見つかりませんでした。"
                Exit Do
            End If
        End If
    Loop
   
End With

Set myRange = ActiveDocument.Range(SS, SS)

With myRange.Find
    .Wrap = wdFindStop
    .Execute findtext:=Selection.Text
End With

myRange.Select
Selection.Collapse direction:=wdCollapseEnd

Set myRange = Nothing

End Sub

| | コメント (0) | トラックバック (0)

2010年4月 6日 (火)

「検索と置換」の画面立ち上げ支援マクロ

水野麻子さんのCT手法を用いて翻訳をする場合、置換を多用します。

CTについては、水野さんのブログのこちらのページに、かなり細かく説明されています。

そんな、置換作業を少しでも迅速にするのに役立つプログラムの紹介です。

▼作用
まず、文字列を選択します。

Replace

プログラムを実行すると、「検索と置換」の画面が立ち上がります。

そのときに、現在選択している文字列が、「検索する文字列」および
「置換後の文字列」のテキストボックスに自動的に入力されています。

Replace2

ただし、使ってみてお気づきの方いらっしゃるかもしれませんが、
通常の「置換と検索」ダイアログとは若干違います。

検索のタブがクリックできない、とか、このダイアログを開いている状態では、
文章にカーソルをもっていけないとか。

▼プログラム文

10        With Selection.Find
20            .ClearFormatting
30            .Replacement.ClearFormatting
40            .Text = Selection.Text           ' ← 「検索する文字列」
50            .Replacement.Text = Selection.Text   ' ← 「置換後の文字列」
60        End With
         
70        On Error Resume Next
80        Dialogs(wdDialogEditReplace).Show

▼プログラム文の解説
こちらのページを参照してご登録ください。

10から60行で、「検索する文字列」と「置換後の文字列」を指定しています。

20行と30行では、文字の書式を解除しています。

40行と50行のSelection.Text が、現在選択されている文字列を意味します。

何も選択していない状態であれば、空欄になります。

70行の命令文は、「エラーが起きたときには無視をして次の処理をしよう」、
というものです。

この命令文がないと、80行でダイアログボックスを開いて
置換処理をした後にエラーが起こります。

ネットでいくつかのプログラム文を調べたのですが、同じような処理に
なっていますね。

80行で、「検索と置換」のダイアログボックスを開きます。

| | コメント (0) | トラックバック (0)

2010年4月 3日 (土)

行を上下する1行マクロ

表示中の画面を1行ずつ上下するキーがあればいいなと思ったことありませんか?

カーソルを画面の上端もしくは下端にまでいとうする必要がありません。
動きは、スクロールバーの矢印のボタンをクリックしたものと同じです。

▼用途
マウスを用いずに画面をスクロールさせる方法です。

ページの最終行で文章が途切れてしまっているとき、次の行を
確認したいことありませんか?

そんなときに、このマクロを動かせば、行単位で画面をスクロール
することができます。

ページ単位での上下はキーボードの[PgUp]キーや[PgDn]キーで
できますが、行単位での操作はできませんよね。

で、この操作をマクロで実現してみました。

FUJITSUのワープロのオアシスシリーズにはついていたキーらしいです。
(私はオアシスは使ったことがないのですが、友人が言っていました)

▼注意事項
キーボードのショートカットに登録することを前提にしたマクロです。
→登録方法は、こちらで紹介したいくつかのページをご覧ください。

そうしないと、このマクロを作動させるために、マウスを持って、
このマクロの実行を指示したのでは、本末転倒ですね。

▼基本例
アクティブになっている画面をスクロールします。

 (上方向) ActiveWindow.ActivePane.SmallScroll Up:=1
 (下方向) ActiveWindow.ActivePane.SmallScroll Down:=1

見ると想像できると思いますが、「Up」と「Down」とで方向を指定しています。
また、その量で、行数を指定することができます。

ActiveWindow.ActivePane」が、選択中のウィンドウ枠を意味します。

| | コメント (0) | トラックバック (0)

2010年3月28日 (日)

下線を解除する1行マクロ

文書中のあらゆる種類の下線を解除するマクロです。
→登録方法は、こちらで紹介したいくつかのページをご覧ください。

▼用途
納品前に書類にメモとして残された下線を一括で解除します。

私は、2つのルールで、翻訳文に下線を入れています。

ルール1
翻訳した文章の精度に不安があるときに通常の下線
(翻訳対象となる原文単独では意味を判断できず、前後を読む必要があるとき)

ルール2
意味を自分で解釈して言葉を追記したときに追記箇所に二重下線

こうすることで、推敲をするときに、下線をひいた部分を中心に意味を
確かめることができるので、推敲時間の短縮ができますし、集中力も維持できます。

いずれの下線もワンクリックで削除するようにマクロを書いて
ツールバーにボタン表示しています。(ボタンの表示方法はこちら

▼基本例
アクティブになっている文書のすべての種類の下線を「下線なし」に変更します。

ActiveDocument.Range.Underline = wdUnderlineNone

ActiveDocument.Range」が書類全体を示しています。

wdUnderlineNone」が「下線なし」という意味です。

なので、上記の式を翻訳すると、こんな感じ。

書類全体下線の種類は=下線なし

▼類似例
選択されている文字の下線の種類を「下線なし」に変更します。

Selection.Range.Underline = wdUnderlineNone

Selection.Range」が選択された文字列を示しています。

▼応用例
文書中の二重下線だけを解除します。

上記のことを、一括置換にて実現しています。

検索する文字列: (書式のみ設定)二重下線
置換後の文字列: (書式のみ設定)下線なし

上記のように設定して、マクロの記録をしても同じような
プログラムを作ることができますね。

Sub 二重下線を下線なしに変換()

      Dim myRange As Range

10    Set myRange = ActiveDocument.Range(0, 0)

20    With myRange.Find
30        .Text = ""
40        .Font.Underline = wdUnderlineDouble '二重下線
50        .Replacement.Text = ""
60        .Replacement.Font.Underline = wdUnderlineNone '下線なし
70        .Forward = True
80        .Wrap = wdFindStop
90        .Execute Replace:=wdReplaceAll
100   End With

110   Set myRange = Nothing

End Sub

| | コメント (0) | トラックバック (0)

2010年3月20日 (土)

蛍光ペンを解除する1行マクロ

文書中の蛍光ペン(どの色でも)を解除するマクロです。
→登録方法は、こちらで紹介したいくつかのページをご覧ください。

▼用途
納品前に書類にメモとして残された蛍光ペンを一括で解除します。

例えば、作業中の文書に「黄」や「明るい緑」の蛍光ペンで
着色することはありませんか?

私は、いくつかのルールに沿って蛍光ペンを活用しています。

例えば、私が日英翻訳で作成する英文明細書の場合、
日本語でメモ書きをしたりします。

なので、納品時にそのメモ書きが残っているとまずいので、
作成した英文明細書中の日本語を検索して蛍光ペンの黄色で
着色するようにしています

そのマクロは以前、こちらに紹介しました。

まだマクロをあんまり知らない時期に書いたものなので、
やたら長いし読みづらいかも。でも、今も活用しています。参考まで。

そのような蛍光ペンを色にかかわらず一括で消すマクロです。

え?わざわざマクロを使う必要はないって?

そうです。これも手動で全選択([Crtl]+[A])して、蛍光ペンの
「蛍光ペンなし」をクリックすれば一瞬ですね。

詳しくは、「Wordでテキパキ」のP.66をご覧ください。

でも、先日紹介した「文字の色を変更する1行マクロ」と同様、
ひとまず、一歩一歩をマクロで実行してみます。

あとで一つのマクロにまとめてみたいと思います。

▼基本例
アクティブになっている文書のすべての蛍光ペンを「蛍光ペンなし」に
変更します。

ActiveDocument.Range.HighlightColorIndex = wdNoHighlight

ActiveDocument.Range」が書類全体を示しています。

wdNoHighlight」が「蛍光ペンなし」という意味です。

なので、上記の式を翻訳すると、こんな感じ。

書類全体の蛍光ペンの色は=蛍光ペンなし

▼類似例
選択されている文字の色を「自動」に変更します。

Selection.Range.HighlightColorIndex = wdNoHighlight

Selection.Range」が選択された文字列を示しています。

▼応用例
黄色の蛍光ペンだけを解除します。

まず、蛍光ペンの箇所を探します。(20行から70行)

見つかったら、蛍光ペンの色が黄色の場合には、
その蛍光ペンの色を「蛍光ペンなし」に変換します。(80行~110行)

これをすべての蛍光ペンについて繰り返します。(80行~140行)

Sub 蛍光ペン黄をなしに変換()

      Dim myRange As Range

10    Set myRange = ActiveDocument.Range(0, 0)

20    With myRange.Find
30        .Text = ""
40        .Highlight = True
50        .Forward = True
60        .Wrap = wdFindStop
70        .Execute
80        Do While .Found = True
90            If myRange.HighlightColorIndex = wdYellow Then
100               myRange.HighlightColorIndex = wdNoHighlight
110           End If
120           myRange.Collapse direction:=wdCollapseEnd
130           .Execute
140       Loop
150   End With

160   Set myRange = Nothing

End Sub

| | コメント (0) | トラックバック (0)

より以前の記事一覧